|
123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124 |
- ###| CMAKE Kiibohd Controller KLL Configurator |###
- #
- # Written by Jacob Alexander in 2014 for the Kiibohd Controller
- #
- # Released into the Public Domain
- #
- ###
-
-
- ###
- # Check if KLL compiler is needed
- #
-
- if ( "${MacroModule}" STREQUAL "PartialMap" )
-
-
-
- ###
- # KLL Installation (Make sure repo has been cloned)
- #
-
- if ( NOT EXISTS "${PROJECT_SOURCE_DIR}/kll/kll.py" )
- # Make sure git is available
- find_package ( Git REQUIRED )
-
- # Clone kll git repo
- execute_process ( COMMAND ${GIT_EXECUTABLE} clone https://github.com/kiibohd/kll.git
- WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
- )
- endif () # kll/kll.py exists
-
-
-
- ###
- # Prepare KLL layout arguments
- #
-
- #| KLL_DEPENDS is used to build a dependency tree for kll.py, this way when files are changed, kll.py gets re-run
-
- #| Search for capabilities.kll in each module directory
- foreach ( DIR ${ScanModulePath} ${MacroModulePath} ${OutputModulePath} ${DebugModulePath} )
- # capabilities.kll exists, add to BaseMap
- set ( filename "${PROJECT_SOURCE_DIR}/${DIR}/capabilities.kll" )
- if ( EXISTS ${filename} )
- set ( BaseMap_Args ${BaseMap_Args} ${filename} )
- set ( KLL_DEPENDS ${KLL_DEPENDS} ${filename} )
- endif ()
- endforeach ()
-
- #| If set BaseMap cannot be found, use default map
- set ( pathname "${PROJECT_SOURCE_DIR}/${ScanModulePath}" )
- if ( NOT EXISTS "${filename}/${BaseMap}.kll" )
- set ( BaseMap_Args ${BaseMap_Args} ${pathname}/defaultMap.kll )
- set ( KLL_DEPENDS ${KLL_DEPENDS} ${pathname}/defaultMap.kll )
- else ()
- set ( BaseMap_Args ${BaseMap_Args} ${pathname}/${BaseMap}.kll )
- set ( KLL_DEPENDS ${KLL_DEPENDS} ${pathname}/${BaseMap}.kll )
- endif ()
-
- #| Configure DefaultMap if specified
- if ( NOT "${DefaultMap}" STREQUAL "" )
- set ( DefaultMap_Args -d )
-
- string ( REPLACE " " ";" MAP_LIST ${DefaultMap} ) # Change spaces to semicolons
- foreach ( MAP ${MAP_LIST} )
- # Check if kll file is in build directory, otherwise default to layout directory
- if ( EXISTS "${PROJECT_BINARY_DIR}/${MAP}.kll" )
- set ( DefaultMap_Args ${DefaultMap_Args} ${MAP}.kll )
- set ( KLL_DEPENDS ${KLL_DEPENDS} ${MAP}.kll )
- else ()
- set ( DefaultMap_Args ${DefaultMap_Args} ${PROJECT_SOURCE_DIR}/kll/layouts/${MAP}.kll )
- set ( KLL_DEPENDS ${KLL_DEPENDS} ${PROJECT_SOURCE_DIR}/kll/layouts/${MAP}.kll )
- endif ()
- endforeach ()
- endif ()
-
- #| Configure PartialMaps if specified
- if ( NOT "${PartialMaps}" STREQUAL "" )
- # For each partial layer
- foreach ( MAP ${PartialMaps} )
- set ( PartialMap_Args ${PartialMap_Args} -p )
-
- # Combine each layer
- string ( REPLACE " " ";" MAP_LIST ${MAP} ) # Change spaces to semicolons
- foreach ( MAP_PART ${MAP_LIST} )
- # Check if kll file is in build directory, otherwise default to layout directory
- if ( EXISTS "${PROJECT_BINARY_DIR}/${MAP_PART}.kll" )
- set ( PartialMap_Args ${PartialMap_Args} ${MAP_PART}.kll )
- set ( KLL_DEPENDS ${KLL_DEPENDS} ${MAP_PART}.kll )
- else ()
- set ( PartialMap_Args ${PartialMap_Args} ${PROJECT_SOURCE_DIR}/kll/layouts/${MAP_PART}.kll )
- set ( KLL_DEPENDS ${KLL_DEPENDS} ${PROJECT_SOURCE_DIR}/kll/layouts/${MAP_PART}.kll )
- endif ()
- endforeach ()
- endforeach ()
- endif ()
-
-
-
- ###
- # Run KLL Compiler
- #
-
- #| KLL Options
- set ( kll_backend -b kiibohd )
- set ( kll_template -t ${PROJECT_SOURCE_DIR}/kll/templates/kiibohdKeymap.h )
- set ( kll_outputname generatedKeymap.h )
- set ( kll_output -o ${kll_outputname} )
-
- #| KLL Cmd
- set ( kll_cmd ${PROJECT_SOURCE_DIR}/kll/kll.py ${BaseMap_Args} ${DefaultMap_Args} ${PartialMap_Args} ${kll_backend} ${kll_template} ${kll_output} )
- add_custom_command ( OUTPUT ${kll_outputname}
- COMMAND ${kll_cmd}
- DEPENDS ${KLL_DEPENDS}
- COMMENT "Generating KLL Layout"
- )
-
- #| Append generated file to required sources so it becomes a dependency in the main build
- set ( SRCS ${SRCS} ${kll_outputname} )
-
-
-
- endif () # PartialMap
-
|